LC-3 kontrol komutları: BR, JMP, TRAP ve döngüler

Geçen hafta komutlar hep sırayla çalışıyordu: her FETCH, PC’yi bir artırıyordu. Gerçek programlar ise karar verir (if) ve tekrar eder (döngü). Bunun için kontrol komutları (control instructions) var: PC’ye yeni bir değer yazarak sıradaki komutu değiştirirler. LC-3’te bunlar BR, JMP, JSR, TRAP ve RTI. Bu sayfada BR, JMP ve TRAP’i, sonra da onlarla kurulan döngü ve if kalıplarını görüyorsun.

Sınav soruları: BR’yi kodla ya da çöz (offset hesabı), hex olarak verilmiş bir programı çöz ve izle, bir döngünün kaç kez döndüğünü ve sonundaki register değerlerini bul.

BR: koşullu dallanma

0000 | n | z | p | PCoffset9
15-12  11  10   9   8-0

BR, condition code’lara bakar. Komutta 1 olan bitlerden biri o anki condition code ile eşleşirse dallanır: PC ← (artmış PC) + SEXT(PCoffset9). Eşleşmezse hiçbir şey yapmaz, program sıradaki komuta geçer.

İPUCU · BR neye bakıyor? BR, condition code’u en son register’a yazan komutun sonucuna bakar. Arada ST, STR, BR gibi CC’yi değiştirmeyen komutlar olabilir; onlar sayılmaz. Bir register’ı test etmek istiyorsan önce onu bir yere yaz: ADD R1, R1, #0 CC’yi R1’e göre ayarlar.

Offset hesabı

$\text{PCoffset9} = \text{hedef} - (\text{BR'nin adresi} + 1)$

Aralık -256..+255. Geriye (döngünün başına) dallanırken offset negatiftir.

Kodlama örneği: BRn LOOP x3008’de, LOOP = x3002.

offset = x3002 - x3009 = -7
-7 (9 bit) = 1 1111 1001
0000 100 111111001 = x09F9

Çözme örneği: x0BFC, x3020’de.

0000 101 111111100
n=1 z=0 p=1  → BRnp
offset = 1 1111 1100 = -4
hedef = x3021 - 4 = x301D

JMP ve RET

1100 | 000 | BaseR | 000000

PC ← BaseR. Hedef bir register’da olduğu için belleğin her yerine atlayabilir (BR sadece ±256). JMP R2 = xC080. RET, JMP R7’nin takma adıdır (xC1C0); alt programdan ya da TRAP rutininden dönmek için kullanılır.

TRAP

1111 | 0000 | trapvect8

1. R7 ← PC (artmış PC, dönüş adresi).
2. PC ← M[ZEXT(trapvect8)]: x0000-x00FF arasındaki trap vector table’dan rutinin adresini al.

Döngü kalıpları

Sayaçlı döngü (counter-controlled)

Kaç kez döneceğin baştan belli. Sayaç bir register’da tutulur, her turda azaltılır, sıfır olunca çıkılır.

Çözümlü örnek: çarpma. LC-3’te MUL yok; 6 × 4 = 6 + 6 + 6 + 6.

        .ORIG x3000
        AND  R3, R3, #0    ; R3 = 0 (sonuç)
        LD   R1, X         ; R1 = 6
        LD   R2, Y         ; R2 = 4 (sayaç)
LOOP    ADD  R3, R3, R1    ; R3 += 6
        ADD  R2, R2, #-1   ; sayaç--
        BRp  LOOP          ; sayaç > 0 ise tekrar
        HALT
X       .FILL #6
Y       .FILL #4
        .END

tur   R3    R2   CC   BRp
 1     6     3    P   dön
 2    12     2    P   dön
 3    18     1    P   dön
 4    24     0    Z   düş

Sonuç R3 = 24. Makine kodu:

x3000 x56E0  AND R3, R3, #0
x3001 x2205  LD  R1, X       (x3002 + 5 = x3007)
x3002 x2405  LD  R2, Y       (x3003 + 5 = x3008)
x3003 x16C1  ADD R3, R3, R1
x3004 x14BF  ADD R2, R2, #-1
x3005 x03FD  BRp x3003       (x3006 - 3)
x3006 xF025  HALT

TUZAK · bir tur fazla. BRp yerine BRzp yazarsan R2 = 0 iken de döner, 5 tur çalışır, sonuç 30 olur. Sayacı 0’da bitirmek istiyorsan BRp kullan.

Sentinel döngü

Kaç eleman olduğu bilinmiyor; listenin sonunda özel bir değer (sentinel, genelde 0) var. Her eleman yüklenir, sentinel ise çıkılır.

Çözümlü örnek: negatifleri say.

        AND  R2, R2, #0     ; sayaç = 0
        LEA  R1, DATA       ; R1 = dizinin adresi
LOOP    LDR  R3, R1, #0     ; R3 = *R1, CC ayarlanır
        BRz  DONE           ; 0 → bitti
        BRp  NEXT           ; pozitif → sayma
        ADD  R2, R2, #1     ; negatif → say
NEXT    ADD  R1, R1, #1     ; sonraki eleman
        BRnzp LOOP
DONE    ST   R2, RESULT
        HALT
RESULT  .BLKW 1
DATA    .FILL #5
        .FILL #-3
        .FILL #-8
        .FILL #2
        .FILL #-1
        .FILL #0

Sonuç RESULT = 3. BRz ile BRp arka arkaya aynı CC’ye bakar, çünkü BR CC’yi değiştirmez.

if ve if/else

Kalıp: koşulun tersiyle atla. “x negatifse şunu yap” yazmak için “x negatif değilse (zp) atla” yazarsın.

Mutlak değer:

        LD   R1, V          ; CC = V'nin işareti
        BRzp DONE           ; negatif değilse atla
        NOT  R1, R1         ; R1 = -R1
        ADD  R1, R1, #1
DONE    ST   R1, V
        HALT
V       .FILL #-25

Sonuç V = 25.

if/else: iki sayının büyüğü.

        LD   R1, A
        LD   R2, B
        NOT  R3, R2
        ADD  R3, R3, #1
        ADD  R3, R1, R3     ; R3 = A - B, CC ayarlandı
        BRn  BBIG           ; A < B ise else kısmına
        ADD  R4, R1, #0     ; then: R4 = A
        BRnzp END           ; else'i atla
BBIG    ADD  R4, R2, #0     ; else: R4 = B
END     HALT
A       .FILL #-4
B       .FILL #9

Sonuç R4 = 9. Then bloğunun sonundaki koşulsuz BRnzp END olmazsa program else bloğuna da düşer.

Hex’ten programı okumak

Sınavda bazen sadece makine kodu verilir. Tarif:

1. Her kelimeyi 16 bite aç, opcode’a bak.
2. Komutu assembly olarak yaz; BR hedeflerini adresle hesapla.
3. Bir iz tablosu kur (register’lar, CC, dallanma).

x3000 x5020  AND R0, R0, #0
x3001 x1225  ADD R1, R0, #5
x3002 x1001  ADD R0, R0, R1
x3003 x127E  ADD R1, R1, #-2
x3004 x03FD  BRp x3002
x3005 xF025  HALT

R1: 5 → 3 → 1 → -1     R0: 5 → 8 → 9     sonuç R0 = 9

Sık yapılan hatalar

        AND  R3, R3, #0
        LD   R1, X
        LD   R2, Y
LOOP    ADD  R3, R3, R1
        ADD  R2, R2, #-1
        BRp  LOOP
        HALT
X       .FILL #6
Y       .FILL #4

        AND  R2, R2, #0
        LEA  R1, DATA
LOOP    LDR  R3, R1, #0
        BRz  DONE
        BRp  NEXT
        ADD  R2, R2, #1
NEXT    ADD  R1, R1, #1
        BRnzp LOOP
DONE    ST   R2, RESULT
        HALT
RESULT  .BLKW 1
DATA    .FILL #5
        .FILL #-3
        .FILL #-8
        .FILL #2
        .FILL #-1
        .FILL #0